Schwarzschild solution using standard 
spherical coordinates

Defining coordinates, the metric, connection, Ricci and Einstein tensors

(* we define our coordinates *)
X={t,r,θ,ϕ};

(* metric components *)
g={{-Exp[A[r]],0,0,0},{0,Exp[B[r]],0,0},{0,0,r^2,0},{0,0,0,r^2 Sin[θ]^2}};

(* inverse metric *)
gup=Simplify[Inverse[g]];

(* here we display the metric and inverse metric in matrix form *)
MatrixForm[g]
MatrixForm[gup]

(* Christoffel symbol Γ_mn^c, the first two indices are the lower one, the final index is the upper index. Ricci tensor is defined with two lower indices *)
Chr=Table[Sum[1/2*gup[[c,d]](D[g[[d,m]],X[[n]]]+D[g[[n,d]],X[[m]]]-D[g[[m,n]],X[[d]]]),{d,1,4}],{m,1,4},{n,1,4},{c,1,4}];
(* Riemann tensor R_adf^b *)
Riemann=Table[
D[Chr[[a,f,b]],X[[d]]]-
D[Chr[[d,f,b]],X[[a]]]+
Sum[Chr[[d,s,b]]*Chr[[a,f,s]],{s,1,4}]-
Sum[Chr[[a,s,b]]*Chr[[d,f,s]],{s,1,4}],{a,1,4},{d,1,4},{f,1,4},{b,1,4}];
Ricci=Table[Sum[Riemann[[aa,bb,cc,bb]],{bb,1,4}],{aa,1,4},{cc,1,4}];

(* Here we finally define the Ricci scalar and the Einstein tensor *)
Ricciscalar=Sum[gup[[q,b]]Ricci[[q,b]],{q,1,4},{b,1,4}];
G=Simplify[Table[Ricci[[m,n]]-1/2*g[[m,n]]*Ricciscalar,{m,1,4},{n,1,4}]];

The Einstein field equations

(* We compute the entire set of Einstein field equations, these are 10 equations in total, however, only two equations are independent in this case *)
G

(* We select two components of the Einstein tensor to solve the field equations and slightly modify the equations for easier subsequent use *)
eqn1=G[[1,1]]r/(E^(A[r]-B[r]));
eqn2=G[[2,2]]r;

(* the first field equation only depends on B and hence we solve this *)
DSolve[eqn1==0,B[r],r]/.C[1]->Log[C1]
(* we replace the default constant of integration by something more suitable *)

(* we can now add up the first and second equation *)
eqn1+eqn2//Simplify

(* This implies that A and B should only differ by a constant *)

The Schwarzschild solution

(* we now use the found solution and look at the resulting metric *)
B[r_]:=-Log[1+(C1/r)];
A[r_]:=-B[r]+C2;

g

(* the constant C2 can be set to zero by rescaling the time coordinate, while we identify C1 with -2M to arrive at the Schwarschild solution *)

g/.C2->0/.C1->-2M

Riemann and Ricci tensors

(* Some components of the Riemann tensor are non-zero and diverge as r -> 0 *)
Riemann/.C2->0/.C1->-2M//Simplify

(* As expected, all Ricci tensor components vanish identically *)
Ricci/.C2->0/.C1->-2M//Simplify